Experiment 1 — 1 of 1

"Experiment 1" by Aaron Reed

The story description is "Giving objects in a story world symbolic weight has often been done by hand, but rarely procedurally. Here's one method for doing so.".

Include Plurality by Emily Short. Release along with the source text and an interpreter.

The Wilderness is a room.

[Let's imagine a basic story about a young astronomer alone on a backpacking trip. He's engaged to be married, but is worried about how this will affect his career. He's also starting to worry that he may be lost, and strange hallucinations make him wonder if he is losing his mind. How might we encode these thematic elements into our story?]

A theme is a kind of thing. being lost, the wild, fear, change, cold, astronomy, what's really important, career, marriage, and senility are themes.

[The various things in our story world should connect to these abstract ideas.]

Symbolizing relates one theme (called the metaphor) to one thing. The verb to symbolize (he symbolizes, they symbolize, he symbolized, it is symbolized, he is symbolizing) implies the reversed symbolizing relation.

The player holds a water bottle. The bottle symbolizes the wild. The player wears a pendant. The pendant symbolizes marriage. The stars are a plural-named backdrop. They are everywhere. They symbolize astronomy. A jacket is here. It symbolizes cold. A broken compass is here. It symbolizes being lost.

[What's interesting, though, is how the themes relate to each other.]

Suggesting relates various themes to each other. The verb to suggest (he suggests, they suggest, he suggested, it is suggested, he is suggesting) implies the suggesting relation.

Being lost suggests fear and the wild. The wild suggests what's really important and change. Fear suggests change and senility. Change suggests what's really important and senility. Cold suggests the wild and astronomy. Astronomy suggests career and what's really important. What's really important suggests marriage and change. Senility suggests fear. Marriage suggests change.

[Now, we can trace a path of connection between any object in the game world and any theme. Let's say that, at any point in our story, one theme is dominant.]

The dominant metaphor is a theme that varies.

[Let's find the connection between any object acted upon and the dominant metaphor.]

Every turn when the noun is a thing:

carry out the finding meaning in activity with the noun.

Finding meaning in something is an activity.

For finding meaning in something (called the token):

say "Ah, [the token]. [Cap It-they of token] remind[s] you of ";

let current idea be the metaphor of the token;

if current idea is not a theme:

say "nothing in particular.";

stop;

say the current idea;

while current idea is not the dominant metaphor:

let the next idea be the next step via the suggesting relation from current idea to the dominant metaphor;

if the next idea is not a theme:

say ", and nothing else";

stop;

say ", then [the next idea]";

now current idea is next idea;

say "."

[To test this, let's create a method for setting and revealing the dominant metaphor.]

When play begins: now the left hand status line is "[the dominant metaphor]".

Carry out waiting: now the dominant metaphor is a random theme.

[Now we have a crude but procedural method of tying any object to any theme, which reveals interesting things about the player character in a way that doesn't rely on hand-authored text. For instance, examining the stars when the dominant metaphor is "change" finds a path between through "what's really important," which reveals that both astronomy and change are important to our protagonist. ]