movies — 1 of 1

"movies" by Aaron Reed

The Mind of a Screenwriter is a room. "Reload to generate more."

Release along with an interpreter and the source text.

When play begins:

repeat with X running from 1 to 100:

let newtitle be indexed text;

now newtitle is a random movie title;

say "[newtitle][line break]".

To decide what indexed text is a random movie title:

let title be indexed text;

now title is "[one of][ProAdj-Noun][or][ProNumAdjNoun][or][FirstLast][or][FirstsNoun][or][ProAdjChar][or][FirstConnectorFirst][or][PositionNoun][or][ConnectorNoun][or][FirstCharMod][or][PronounNoun][or][CharacterConnectorPlace][or][ThePlaceGrandiose][or][OddballName][or][OddballName][or][CharacterOfPlace][or][ThePersonStory][or][CharacterAndTheThing][at random]";

if a random chance of 1 in 6 succeeds, now title is "[title][sequel]";

if a random chance of 1 in 50 succeeds, now title is "[movie first name] [movie last name] presents [title]";

decide on "[title in title case]".

To say CharacterAndTheThing: say "[one of][movie first name][or][movie generic character][as decreasingly likely outcomes] [movie last name] [one of]And The[or]Battles The[or]And the quest for the[or]Takes On[as decreasingly likely outcomes] [one of][movie adjective][or][movie grandiose adjective][at random] [one of][movie noun][or][movie grandiose noun][as decreasingly likely outcomes]".

To say ThePersonStory: say "The [movie first name] [movie last name] [movie story word]".

To say sequel: say "[one of] [movie sequel number][or]: [a random movie title][or] [movie sequel phrase][as decreasingly likely outcomes]".

To say movie sequel number: say "[one of]2[or]3D[or]3[or]4[or]5[as decreasingly likely outcomes]".

To say movie sequel phrase: say "[one of]: The Second Chapter[or]: The [movie story word] Continues[or]Again[or]Returns[or]: The Final [movie story word][at random]".

To say OddballName: say "[one of][movie position] and [movie position][or][movie first name] & [movie first name] & [movie first name][or][modifier movie place] [movie grandiose noun][or][movie adjective][or]The [movie story word] of [movie character][or][movie place][or]The [movie grandiose adjective] [movie grandiose adjective] [movie character][or]The [movie sequel preface] Of [movie character], [movie grandiose adjective] [movie generic character][at random]".

To say movie sequel preface: say "[if a random chance of 1 in 2 succeeds][one of]Further[or]Continuing[or]Next[or]Final[or]First[or]Untold[or][movie adjective][at random] [end if][if a random chance of 1 in 5 succeeds][movie adjective] [end if][one of]Adventures[or]Chronicles[or]Exploits[or]Tragedy[or]Road Trip[or]Expedition[or]Battle[or]Testimony[at random]".

To say ThePlaceGrandiose: say "The [movie place] [movie grandiose noun]".

To say CharacterConnectorPlace: say "[movie character] [movie connector] [movie place]".

To say PronounNoun: say "[one of][movie pronoun][or][movie adjective][or][movie pronoun] [movie adjective][at random] [movie noun]".

To say AdjectiveNoun: say "[movie adjective] [movie noun]".

To say FirstCharMod: say "[one of][movie first name][or][movie character title][at random] [movie last name][one of], [movie generic character] [or][at random] [one of][movie modifier][or][at random]".

To say ConnectorNoun: say "[movie connector] [movie grandiose noun]".

To say ProAdj-Noun: say "[one of][movie pronoun][or][movie adjective][purely at random] [movie noun]".

To say ProNumAdjNoun: say "[one of][movie pronoun] [or][purely at random][a random number from two to eight in words] [one of][movie adjective] [or][purely at random][movie plural noun]".

To say PositionNoun: say "[movie position] [one of][movie pronoun] [or][at random][movie grandiose noun]"

To say ProAdjChar: say "[movie pronoun] [one of][movie adjective][or][movie grandiose adjective][at random] [movie character]".

To say movie character: say "[one of][if a random chance of 1 in 5 succeeds][movie character title][otherwise][movie first name][end if] [movie last name][or][movie last name][or][movie character title] [movie generic character][as decreasingly likely outcomes]".

To say movie generic character: say "[one of]Cat[or]Nanny[or]Uncle[or]Creature[or]Moron[or]Hero[or]President[or]Grandma[or]Dad[or]Prince[or]Master[or]Bishop[or]Inspector[or]Kid[or]Soldier[or]Teacher[or]Wizard[or]Secretary[or]Pirate[or]Time Traveler[or]Ninja[or]Zombie[or]Warrior[or]Schmuck[or]Inmate[or]Candidate[at random]".

To say movie character title: say "[one of]Mr.[run paragraph on][or]Mrs.[run paragraph on][or]Mister[or]Miss[or]Doctor[or]Lady[or]Captain[or]Professor[or]Nurse[or]General[at random]".

To say FirstLast: say "[movie first name] [movie last name]".

To say FirstsNoun: say "[movie first name]'s [one of][movie noun][or][movie plural noun][at random]".

To say FirstConnectorFirst: say "[one of][movie first name][or][movie last name][at random] [movie connector] [one of][movie first name][or][movie last name][at random]".

To say movie connector: say "[one of]And[or]&[or]Versus[or]Or[or]Against[or]Takes On[or]Finds[as decreasingly likely outcomes]"

To say movie pronoun: say "[one of]The[or]The[or]A[or]His[or]Her[or]Our[or]My[or]Your[or]Their[or]One[as decreasingly likely outcomes]".

To say movie noun: say "[one of]Bridge[or]Morning[or]Umbrella[or]Voyage[or]Box[or]Stair[or]Knife[or]Goodbye[or]Room[or]Letter[or]Gift[or]Secret[or]Job[or]Wedding[or]Club[or]Bequest[or]Promise[or]Betrayal[or]Storm[or]Rose[or]Fuse[or]Child[or]Clock[or]Game[or]Moment[or]God[or]Martyr[or]Victim[or]Treasure[or]Random[at random]".

To say movie plural noun: say "[one of]Secrets[or]Knives[or]Rooms[or]Houses[or]Whisperers[or]Villagers[or]Letters[or]Storms[or]Nights[or]Castles[or]Steps[or]Masks[or]Children[or]Wars[or]Liars[or]Stories[or]Violins[or]Countries[or]Fingers[or]Villains[at random]".

To say movie adjective: say "[one of][movie color][or]Long[or]Big[or]Cool[or]Dark[or]Sweet[or]Last[or]First[or]Smooth[or]Old[or]Sly[or]Itchy[or]Wet[or]Rare[or]Wilted[at random]".

To say movie color: say "[one of]Red[or]Blue[or]Green[or]Crimson[or]Violet[or]Purple[or]Yellow[or]Orange[or]White[or]Black[or]Indigo[at random]".

To say movie grandiose adjective: say "[one of]Fifth[or]Seventh[or]Thirteenth[or]Subtle[or]Whirling[or]Magnificent[or]Unknown[or]Heartless[or]Maximum[or]Terrible[or]Wonderful[or]Exploding[or]Diabolical[or]Extraordinary[or]Deadly[or]Imperial[at random]".

To say movie first name: say "[one of]James[or]John[or]Rob[or]Michael[or]Will[or]Dave[or]Rich[or]Charlie[or]Joe[or]Thomas[or]Kenneth[or]Kevin[or]Mary[or]Jennifer[or]Suzie[or]Dorothy[or]Karen[or]Sandra[or]Donna[or]Taurus[or]Winchester[or]Dorian[or]Nicholas[or]Veronica[or]Venus[or]Jupiter[or]Mitch[or]Jose[or]Carlotta[or]Wilhelm[or]Cho[or]Tamara[or]Vanity[or]Cole[or]Arson[or]Derek[or]Slim[or]Jimmy[or]Carl[or][movie last name][or][movie place][or][movie color][at random]".

To say movie last name: say "[one of]Harbinger[or]Diamond[or]Parrish[or]Washington[or]Raines[or]Quintana[or]Remmington[or]Steele[or]Monsanto[or]Funk[or]Starr[or]Strong[or]Shock[or]Iron[or]Gamble[or]Cinco[or]Blackborn[or]Nixon[or]Sharp[or]Beretta[or]Colt[or]Dakota[or]Griffin[or]Xavier[or]Kingsley[or]Smith[or]Jones[or]Vallarta[or][movie color][or][movie place][or]Cristos[or]Badminton[or]Parker[or]Holmes[or]Harper[or]Romero[or]Hollander[or]Barrett[or]Moody[or]O'Neil[at random]".

To say movie position: say "[one of]Between[or]Among[or]Beyond[or]Before[or]Above[or]Below[or]Around[or]Beside[or]Behind[or]Within[or]Inside[at random]".

To say movie story word: say "[one of]Story[or]Epic[or]Legend[or]Tale[or]Chronicles[or]Diaries[or]Adventure[or]Movie[or]Saga[at random]".

To say movie grandiose noun: say "[one of]Element[or]Conundrum[or]Solution[or]Event[or]Paradox[or]Problem[or]Conspiracy[or]Quorum[or]Diary[or]Citizen[or]Intention[or]Identity[or]Impossibility[or]Concordance[or]Division[or]Incision[or]Countdown[at random]".

To say movie modifier: say "[one of]At large[or]Extraordinaire[or]Again[or]Of [movie place][or]from [movie place][or]Of Mine[or]So [movie adjective][at random]".

To say movie place: say "[one of]London[or]Paris[or]Tokyo[or]Space[or]Kentucky[or]the Pacific[or]Montreal[or]New York[or]Los Angeles[or]Beirut[or]Iraq[or]Iceland[or]the Kremlin[or]Monterey[or]Siberia[or]Tobago[or]India[or]Zaire[or]Maui[or]Arabia[or]California[or]bear country[or]Florida[or]Peyoria[or]Boston[or][movie adjective] falls[or][movie last name] street[or]mount [movie last name][at random]".

To say CharacterOfPlace: say "[movie character][one of] of[or] from[or], [movie generic character] of[as decreasingly likely outcomes] [modifier movie place]".

To say modifier movie place: say "[one of]the rockies[or]the south[or]the wind[or]the asteroids[or]the west[or]the north[or]the arctic[or]the sea[or]the underground[or]the slums[or]the island[or]the district[at random]".